home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
90xx
/
9008a.d64
/
leseroutine 1
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
35 lines
10 REM ERRORLESEROUTINE FUER ALLE SPUREN
20 REM (C) 1986 BY KLAUS RACZEK
30 :
40 DIM R(22): REM FELD FUER LESEROUTINE
50 OPEN1,8,15,"I":REM FEHLERKANAL OEFFNEN UND INITIALISIEREN
60 FORI=0TO22
70 READ R(I): REM MASCHINENPROGRAMM IN
80 NEXT I: REM FELD R() EINLESEN
90 PRINT"[147]EINLESEN EINES SEKTORS"
100 INPUT"WELCHE SPUR (1-40)";SP:R(1)=SP
110 INPUT"WELCHER SEKTOR";SE:R(5)=SE
115 INPUT"WELCHE ID (ODER RETURN)";ID$
116 IFID$<>""THENPRINT#1,"M-W"CHR$(18)CHR$(0)CHR$(2)ID$
120 FORI=0TO22
130 PRINT#1,"M-W"CHR$(I)CHR$(4)CHR$(1)CHR$(R(I)):REM PROGRAMM IN PUFFER SCHREIBE
140 NEXT I
145 PRINT#1,"M-W"CHR$(106)CHR$(0)CHR$(1)CHR$(133): REM BEI ERROR NICHT KLAPPERN
150 PRINT#1,"M-E"CHR$(0)CHR$(4):REM PROGRAMM IN PUFFER AUSFUEHREN
160 INPUT#1,A,B$,C,D:PRINT:PRINTA;B$;C;D:REM FEHLERKANAL LESEN UND ZEIGEN
170 FORI=1TO3000:NEXT
180 :
190 DATA 169,18,133,6,169,1,133,7,169,128
200 DATA 162,0,141,77,2,133,0,141,91,2,76,153,213
210 :
220 :
230 PRINT"ANZEIGEN DES BLOCKINHALTS":FORI=1TO2000:NEXT
240 REM 256 BYTES
250 :
260 FORI=0TO255STEP16:PRINT"[147]BYTE BYTE BYTE"
265 PRINT"NUMMER DEZIMAL ASCII":FORJ=0TO15
270 PRINT#1,"M-R"CHR$(I+J)CHR$(3)
280 GET#1,A$:A=ASC(A$+CHR$(0)):REM EINE BYTE LESEN
290 PRINT""I+J,A,A$"":REM AUSGEBEN: BYTENUMMER, ASC-WERT, ASCII-ZEICHEN
300 NEXT:PRINT"TASTE":POKE198,0:WAIT198,1:NEXT